1枚のRawImageをRGBで3枚に分割して加算合成するジオメトリシェーダ

舌の根も乾かないうちにジオメトリシェーダを書いたので記事にしておきます

Shader "UI/Default(Geometry) RGB Divide"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)

        _StencilComp ("Stencil Comparison", Float) = 8
        _Stencil ("Stencil ID", Float) = 0
        _StencilOp ("Stencil Operation", Float) = 0
        _StencilWriteMask ("Stencil Write Mask", Float) = 255
        _StencilReadMask ("Stencil Read Mask", Float) = 255

        _ColorMask ("Color Mask", Float) = 15
		_Distance("Distance", Float) = 0

        [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Stencil
        {
            Ref [_Stencil]
            Comp [_StencilComp]
            Pass [_StencilOp]
            ReadMask [_StencilReadMask]
            WriteMask [_StencilWriteMask]
        }

        Cull Off
        Lighting Off
        ZWrite Off
        ZTest Always
        Blend One One
        ColorMask [_ColorMask]

        Pass
        {
            Name "Default"
        CGPROGRAM
            #pragma vertex vert
			#pragma geometry geom
            #pragma fragment frag
            #pragma target 5.0

            #include "UnityCG.cginc"
            #include "UnityUI.cginc"

            #pragma multi_compile __ UNITY_UI_CLIP_RECT
            #pragma multi_compile __ UNITY_UI_ALPHACLIP

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct g2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                float2 texcoord  : TEXCOORD0;
                float4 worldPosition : TEXCOORD1;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            sampler2D _MainTex;
            fixed4 _Color;
            fixed4 _TextureSampleAdd;
            float4 _ClipRect;
            float4 _MainTex_ST;
			float _Distance;

			//Geometryシェーダで処理するので何もしない
			appdata_t vert(appdata_t v)
            {
				return v;
            }

			[maxvertexcount(9)]
			void geom(triangle appdata_t input[3], inout TriangleStream<g2f> outStream)
			{
				float2 offsets[3] = { float2(0,1),float2(1,0),float2(-1,0) };//ずらす方向ベクトル
				float4 colors[3] = { float4(1,0,0,1),float4(0,1,0,1),float4(0,0,1,1) };

				[unroll]
				for (int i = 0; i < 3; i++)
				{
					[unroll]
					for (int j = 0; j < 3; j++)
					{
						appdata_t v = input[j];

						g2f o;
						UNITY_SETUP_INSTANCE_ID(v);
						UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
						o.worldPosition = v.vertex;

						o.worldPosition.xy += offsets[i] * _Distance;

						o.vertex = UnityObjectToClipPos(o.worldPosition);
						o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
						o.color = v.color * _Color * colors[i];
						outStream.Append(o);
					}
					outStream.RestartStrip();
				}
			}

            fixed4 frag(g2f IN) : SV_Target
            {
                half4 color = (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd) * IN.color;

                #ifdef UNITY_UI_CLIP_RECT
                color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
                #endif

                #ifdef UNITY_UI_ALPHACLIP
                clip (color.a - 0.001);
                #endif

                return color;
            }
        ENDCG
        }
    }
}

_Distanceをいじると、ずらし幅を調整できます。
本当にやりたい事はこれじゃないんだけども、意外とあっさりできたので記事化…！